Bonjour,
désolé pour Patrick et encore plus pour son épouse.... condoléances!
Euh j'ai cliqué sur le lien pour la cagnotte mais ça mouline et ça s'ouvre pas, je sais pas si le lien est mort ou en panne, mais je voulais juste vous tenir au courant...

Bonjour @henry.cremieux personne en particulier n'est en charge de ces LISP. C’est à la communauté, c'est à dire nous tous de les faire vivre. Pour ce qui concerne la cagnotte, elle fonctionne, pas de problème.

Patrick Emin animateur de la communauté francophone


Vous avez trouvé un message utile? Alors donnez un "J'aime" à ce message!
Votre question a eu une réponse satisfaisante? Voulez vous avoir l'amabilité de cliquer sur le bouton  APPROUVER LA SOLUTION  en bas de la réponse qui apporte une solution?
Signez notre Livre d'Or

Hello 

RAPPEL: les routines LSP de Patrick_35 que des milliers de gens utilisent représentent N centaines d heures d investissement personnel et CE BENEVOLEMENT ! Encore MERCI Patrick !!

J utilise qq routines de Patrick sur ACAD MAP 2020 sans souci... 

A propos SVP quelles routines par exemple ne fonctionnent pas sur ACAD 2020 ?

Regards, Patrice "triste" 

Bonjour.

Les LISP du regretté Maître Patrick_35 sont aussi disponibles sur une communauté très active : CadXP.com 

Denis...

Bon après-midi,
J'utilise le SYN.LSP V1.50 de patrick_35 depuis un certain temps maintenant.
Fonctionne bien, mais est-il également possible de conserver la justification de l'attribut ?

Cordialement,
Jaap Marchal.
Ce message a été créé avec google translate, il peut donc contenir des erreurs.

;;;=================================================================
;;;
;;; SYN.LSP V1.50
;;;
;;; Synchroniser en conservant ou pas la valeur, la position
;;; et l'angle des attributs.
;;;
;;; Copyright (C) Patrick_35
;;;
;;;=================================================================

(defun patrick:synchro_att(cmd / att blo boite_dialogue choix def doc ent lst lstbl msg nombl
				 ecr_att oui-non question rep s sel str *errret*)

  (defun *errret* (msg)
    (or (member (strcase msg) '("FUNCTION CANCELLED" ""QUIT / EXIT ABORT"" "FONCTION ANNULEE" "QUITTER / SORTIR ABANDON"))
      (princ (strcat "\nErreur : " msg))
    )
    (vla-endundomark doc)
    (setq *error* s)
    (princ)
  )

  (defun nombl(bl)
    (if (vlax-property-available-p bl 'effectivename)
      (vla-get-effectivename bl)
      (vla-get-name bl)
    )
  )

  (defun msg(js)
    (if js
      (princ (strcat "\nSélection actuel : " js))
      (princ "\nSélection actuel : Tout")
    )
  )

  (defun bits(var bit)
    (boole 6 var bit)
  )

  (defun choix(chx cmd / bl js lst nom sel)
    (princ "\nSélectionnez le(s) bloc(s) : ")
    (and (ssget (list (cons 0 "insert") (cons 66 1)))
      (progn
	(vlax-for bl (setq sel (vla-get-activeselectionset doc))
	  (or (member (setq nom (nombl bl)) lst)
	    (setq lst (cons nom lst))
	  )
	  (redraw (vlax-vla-object->ename bl) 4)
	)
	(foreach nom lst
	  (and (eq (vla-get-isxref (vla-item (vla-get-blocks doc) nom)) :vlax-false)
	    (if js
	      (setq js (strcat js "," nom))
	      (setq js nom)
	    )
	  )
	)
	(vla-delete sel)
      )
    )
    (or js (setq js chx))
    (and cmd (msg js))
    js
  )

  (defun boite_dialogue(titre / blo choix_aucun choix_lst choix_tout chx dcl fil js liste_bl
				loc rech rep res sel str tmp vao)

    (defun choix_lst(val / pos lst)
      (while (setq pos (read val))
	(if lst
	  (setq lst (strcat lst "," (nth pos liste_bl)))
	  (setq lst (nth pos liste_bl))
	)
	(setq val (substr val (+ 2 (strlen (itoa pos)))))
      )
      (setq js lst
	    chx "Nom"
      )
    )

    (defun choix_tout(/ pos val str)
      (setq pos 0)
      (while (setq val (nth pos liste_bl))
	(if str
	  (setq str (strcat str " " (itoa pos)))
	  (setq str (itoa pos))
	)
	(setq pos (1+ pos))
      )
      (setq js nil
	    chx "Tout"
	    sel str
      )
      (set_tile "lst" sel)
    )

    (defun choix_aucun()
      (setq js nil
	    chx nil
	    sel ""
      )
      (set_tile "lst" sel)
    )

    (defun rech()
      (and (member (substr str 1 loc) liste_bl)
	   (setq vao (itoa (- (length liste_bl) (length (member (substr str 1 loc) liste_bl)))))
	(if sel
	  (setq sel (strcat sel " " vao))
	  (setq sel vao)
	)
      )
    )

    (setq tmp (vl-filename-mktemp "ret" nil ".dcl")
	  fil (open tmp "w")
    )
    (foreach txt '(	"ret : dialog {"
			"  key = titre;"
			"  is_cancel = true;"
			"  fixed_width = true;"
			"  alignment = centered;"
			"  : list_box {label = \"Blocs\"; key = \"lst\"; multiple_select = true; width = 40; height = 20;}"
			"  : boxed_column {"
			"    label = \"Conserver dans les attributs\";"
			"    : row {"
			"      : column {"
			"	: toggle {label = \"Les valeurs\";   key = \"val\";}"
			"	: toggle {label = \"Les styles\";    key = \"sty\";}"
			"      }"
			"      : column {"
			"	: toggle {label = \"Les positions\"; key = \"pos\";}"
			"	: toggle {label = \"Les angles\";    key = \"ang\";}"
			"      }"
			"    }"
			"    spacer;"
			"  }"
			"  spacer;"
			"  : row {"
			"    : button {label = \"Tout\";  key = \"tout\";}"
			"    : button {label = \"Aucun\"; key = \"aucun\";}"
			"    : button {label = \">>\";    key = \"sel\";}"
			"    ok_cancel;"
			"  }"
			"}"
		 )
      (write-line txt fil)
    )
    (close fil)
    (vlax-for blo (vla-get-blocks doc)
      (or (wcmatch (vla-get-name blo) "`**,*|*")
	  (eq (vla-get-isxref blo) :vlax-true)
	(vlax-for ent blo
	  (and	(eq (vla-get-objectname ent) "AcDbAttributeDefinition")
		(not (member (vla-get-name blo) liste_bl))
	    (setq liste_bl (cons (vla-get-name blo) liste_bl))
	  )
	)
      )
    )
    (setq liste_bl (acad_strlsort liste_bl)
	  dcl (load_dialog tmp)
	  sel ""
    )
    (while (not (member res '(0 1)))
      (new_dialog "ret" dcl "")
      (start_list "lst")
        (mapcar 'add_list liste_bl)
      (end_list)
      (set_tile "titre" titre)
      (set_tile "lst" sel)
      (and (eq (logand val 2) 2)
        (set_tile "val" "1")
      )
      (and (eq (logand val 4) 4)
        (set_tile "pos" "1")
      )
      (and (eq (logand val 😎 8)
        (set_tile "ang" "1")
      )
      (and (eq (logand val 16) 16)
        (set_tile "sty" "1")
      )
      (action_tile "lst"    "(choix_lst $value)")
      (action_tile "tout"   "(choix_tout)")
      (action_tile "aucun"  "(choix_aucun)")
      (action_tile "val"    "(setq val (bits val 2))")
      (action_tile "pos"    "(setq val (bits val 4))")
      (action_tile "ang"    "(setq val (bits val 8))")
      (action_tile "sty"    "(setq val (bits val 16))")
      (action_tile "sel"    "(done_dialog 2)")
      (action_tile "accept" "(done_dialog 1)")
      (action_tile "cancel" "(done_dialog 0)")
      (setq res (start_dialog))
      (cond
	((eq res 1)
	  (setq rep (list chx js val))
	)
	((eq res 2)
	  (and (setq js (choix js nil))
	    (progn
	      (setq str js
		    sel nil
		    chx "Nom"
	      )
	      (while (setq loc (vl-string-search "," str))
		(rech)
		(setq str (substr str (+ 2 loc)))
	      )
	      (rech)
	      (or sel (setq sel ""))
	    )
	  )
	)
	(T
	  (setq rep (list nil nil val))
	)
      )
    )
    (unload_dialog dcl)
    (vl-file-delete tmp)
    rep
  )

  (defun question(/ choixbl lst rep sel)

    (defun choixbl(chx / js nom pos sel)
      (defun nom(txt / str)
	(setq txt (vl-string-left-trim  " " txt)
	      txt (vl-string-right-trim " " txt)
	)
	(if (tblsearch "block" txt)
	  (setq str txt)
	  (princ (strcat "\nLe bloc \"" txt "\" n'existe pas."))
	)
	(and str
	  (if (and js (wcmatch (strcase js) (strcase (strcat str "," str "`,*" ",*`," str "`,*,*`," str))))
	    (princ (strcat "\nLe bloc \"" str "\" est déjà selectionné."))
	    (if js
	      (setq js (strcat js "," str))
	      (setq js str)
	    )
	  )
	)
      )

      (setq js chx)
      (while (/= (setq sel (getstring t "\nIndiquez le(s) nom(s) du/des bloc(s) : ")) "")
	(while (setq pos (vl-string-search "," sel))
	  (nom (substr sel 1 pos))
	  (setq sel (substr sel (+ 2 pos)))
	)
	(nom sel)
	(msg js)
      )
      (and (eq js chx) (msg js))
      js
    )

    (setq sel "Tout" rep sel)
    (while (/= sel "Fin")
      (initget "Tout Sélection Nom Fin")
      (or (setq sel (getkword (strcat "\nChoix des blocs [Tout/Sélection/Nom/Fin] <" sel "> : ")))
	(progn
	  (setq sel rep)
	  (and (eq rep "Tout")
	    (setq sel "Fin")
	  )
	)
      )
      (cond
	((eq sel "Tout")
	  (setq rep sel)
	)
	((eq sel "Sélection")
	  (setq rep sel
		lst (choix lst T) 
	  )
	)
	((eq sel "Nom")
	  (setq rep sel
		lst (choixbl lst) 
	  )
	)
      )
    )
    (list rep lst)
  )

  (defun oui-non(que o-n / rep)
    (initget "Oui Non")
    (setq rep (getkword (strcat "\n" que " [Oui/Non] <" (if (eq (logand val o-n) o-n) "Oui" "Non") "> : ")))
    (cond
      ((eq rep "Oui")
	(or (eq (logand val o-n) o-n)
	  (setq val (boole 6 val o-n))
	)
      )
      ((eq rep "Non")
	(and (eq (logand val o-n) o-n)
	  (setq val (boole 6 val o-n))
	)
      )
    )
    T
  )

  (defun ecr_att(a b c d)
    (and (vl-catch-all-error-p (vl-catch-all-apply 'vlax-put (list b d c)))
      (vl-catch-all-apply 'vlax-put (list a d c))
    )
  )

  (vl-load-com)
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
	s *error*
	*error* *errret*
  )
  (vla-startundomark doc)
  (if (setq val (getenv "Patrick_35_syn"))
    (setq val (atoi val))
    (setq val 0)
  )
  (if (and (or
	     (and (eq cmd 0)
		  (setq rep (boite_dialogue "SYN V1.50")
			val (nth 2 rep)
			rep (list (nth 0 rep) (nth 1 rep))
		  )
	     )
	     (and (eq cmd 1)
		  (setq rep (question))
		  (oui-non "Conserver la valeur des attributs"   2)
		  (oui-non "Conserver la position des attributs" 4)
		  (oui-non "Conserver l'angle des attributs"     8)
		  (oui-non "Conserver le style des attributs"    16)
	     )
	   )
	   (car rep)
      )
    (progn
      (or (eq (car rep) "Tout")
	  (cadr rep)
	(setq rep (list "Tout" nil))
      )
      (and 
	(if (cadr rep)
	  (ssget "_x" (list (cons 0 "insert") (cons 2 (strcat "`**," (cadr rep))) (cons 66 1)))
	  (ssget "_x" (list (cons 0 "insert") (cons 66 1)))
	)
	(progn
	  (vlax-for blo (setq sel (vla-get-activeselectionset doc))
	    (setq str (nombl blo)
		  att nil
	    )
	    (and (or (eq (car rep) "Tout")
		     (and
		       (cadr rep)
		       (wcmatch (strcase (cadr rep)) (strcase (strcat str "," str "`,*" ",*`," str "`,*,*`," str)))
		     )
		 )
	      (progn
		(foreach ent (vlax-invoke blo 'getattributes)
		  (setq att (cons (list ent
					(vlax-get ent 'textstring)
					(vlax-get ent 'insertionpoint)
					(vlax-get ent 'textalignmentpoint)
					(vlax-get ent 'alignment)
					(vlax-get ent 'rotation)
					(vlax-get ent 'stylename)
					(vlax-get ent 'height)
					(vlax-get ent 'scalefactor)
					(vlax-get ent 'obliqueangle)
				  )
				  att
			    )
		  )
		)
		(setq lst (cons (cons blo att) lst))
		(or (member (nombl blo) lstbl)
		  (setq lstbl (cons (nombl blo) lstbl))
		)
	      )
	    )
	  )
	  (vla-delete sel)
	  (and lst
	    (progn
	      (setq def (getvar "cmdecho"))
	      (setvar "cmdecho" 0)
	      (vlax-for blo (vla-get-blocks doc)
		(and (eq (vla-get-islayout blo) :vlax-false)
		     (setq str (vla-get-name blo))
		     (member str lstbl)
		  (progn
		    (vl-cmdf "_.attsync" "_name" str)
		    (princ (strcat (chr 😎 " pour le bloc " str "."))
		  )
	        )
	      )
	      (setvar "cmdecho" def)
	      (or (zerop val)
		(foreach blo lst
		  (mapcar '(lambda(a b)
			    (and (eq (logand val 2) 2)
			      (vl-catch-all-apply 'vlax-put (list a 'textstring (nth 1 b)))
;			      (ecr_att a (nth 0 b) (nth 1 b) 'textstring)
			    )
			    (and (eq (logand val 16) 16)
			      (progn
				(vl-catch-all-apply 'vlax-put (list a 'stylename    (nth 6 b)))
				(vl-catch-all-apply 'vlax-put (list a 'height       (nth 7 b)))
				(vl-catch-all-apply 'vlax-put (list a 'scalefactor  (nth 8 b)))
				(vl-catch-all-apply 'vlax-put (list a 'obliqueangle (nth 9 b)))
;				(ecr_att a (nth 0 b) (nth 6 b) 'stylename)
;				(ecr_att a (nth 0 b) (nth 7 b) 'height)
;				(ecr_att a (nth 0 b) (nth 8 b) 'scalefactor)
;				(ecr_att a (nth 0 b) (nth 9 b) 'obliqueangle)
			      )
			    )
			    (and (eq (logand val 4) 4)
			      (vl-catch-all-apply 'vla-move (list a (vla-get-insertionpoint a) (vlax-3d-point (nth 2 b))))
;			      (ecr_att a (nth 0 b) (nth 2 b) 'insertionpoint)
			    )
			    (and (eq (logand val 😎 8)
			      (vl-catch-all-apply 'vlax-put (list a 'rotation (nth 5 b)))
;			      (ecr_att a (nth 0 b) (nth 5 b) 'rotation)
			    )
			  )
			  (vlax-invoke (car blo) 'getattributes)
			  (reverse (cdr blo))
		  )
		)
	      )
	      (setenv "Patrick_35_syn" (itoa val))
	    )
	  )
	)
      )
    )
  )
  (vla-endundomark doc)
  (setq *error* s)
  (princ)
)

(defun c:syn()
  (if (zerop (getvar "cmdactive"))
    (patrick:synchro_att 0)
    (patrick:synchro_att 1)
  )
)

(defun c:-syn()
  (patrick:synchro_att 1)
)

(setq nom_lisp "SYN")
(if app
  (if (= (strcase (substr app (1+ (- (strlen app) (strlen nom_lisp))) (strlen nom_lisp))) nom_lisp)
    (princ (strcat "..." nom_lisp " chargé."))
    (princ (strcat "\n" nom_lisp ".LSP Chargé.....Tapez " nom_lisp " pour l'éxecuter.")))
  (princ (strcat "\n" nom_lisp ".LSP Chargé......Tapez " nom_lisp " pour l'éxecuter.")))
(setq nom_lisp nil)
(princ)

Bonjour @Vincent_CAVUOTO , oui c'est toujours possible, cela permettrait aux gens qui sont plutôt débutants dans l'AutoLISP de savoir ne serait-ce que comment charger et lancer un programme. Et puis de donner quelques exemples de ce qu'il a réalisé effectivement.

Patrick Emin animateur de la communauté francophone


Vous avez trouvé un message utile? Alors donnez un "J'aime" à ce message!
Votre question a eu une réponse satisfaisante? Voulez vous avoir l'amabilité de cliquer sur le bouton  APPROUVER LA SOLUTION  en bas de la réponse qui apporte une solution?
Signez notre Livre d'Or

Merci à vous, très sympa de votre part 👌

Ce sera avec plaisir, je suis passionné d'Autocad et c'est juste la reconnaissance méritée pour notre ami Patrick 👍

Ravi de participer à cette belle communauté Autodesk sur laquelle je n'avais pas pris le temps de suivre les sujets.

Au plaisir de vous lire souvent maintenant 😉

Je mettrai le lien de la vidéo dès que ce sera bon.

À bientôt, 

Vincent

Hello @Vincent_CAVUOTO , @patrick.emin 

MERCI pour la Video et voici un vieux (2009) Trombinoscope de cadxp.com ...

Au fait est ce toi Christian @rebcao qui a realise cette image ?

La Sante, Bye, Patrice (The Old French EE Froggy)

Bonjour, la cagnotte envoie sur un lien paypal qui n existe plus. 

Merci !